Macro | Joel's SharePoint Architect Blog

Posts Tagged ‘Macro’

Auto Summary Slides for PowerPoint 2010 VBA Macro with Hyperlinks! Free!

Filed Under : Training by Joel Jeffery

Aug.31,2010

*UPDATE* Here’s the download link to a new version of my PowerPoint template with VBA Macro, updated to auto generate hyperlinks and summary pages for your PowerPoint 2010 slide decks.

In my first post on creating Auto Summary Slides for PowerPoint 2010, I gave you a VBA macro and PowerPoint template showing how to create summary slides based upon the titles of those selected with one mouse click.

By popular demand, I’ve added an extra feature to the Macro. You now have two choices: either have the original behaviour of a text-only summary page, or use the new extended version that makes every summary item a hyperlink to the original slide.

Once again, I’m making this free under the Creative Commons Public Domain license.

'''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
''' InsertSummary()
''' by Joel Jeffery (http://joelblogs.co.uk) August 2010
''' Creates a Summary Slide for PowerPoint 2010
''' (and probably 2007 too!)
''' Depends: Requires QSortInPlace by Chip Pearson
''' Usage: Select Slides (e.g. in Slide Sorter) and run
''' this macro.
''' License: Creative Commons Public Domain 2010
'''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
Sub InsertSummary(Optional CreateHyperlinks As Boolean)
    Dim i As Integer
    Dim strSel As String, strTitle As String
    Dim summary As Slide
    
    'Only run if we've got something selected
    If ActiveWindow.Selection.SlideRange.Count > 0 Then
        'Array to hold the order of the slides...
        'We do this or we build the ToC in the order
        'in which the slides were selected :)
        Dim slideOrder() As Integer
        
        'Size this to the number of slides selected
        ReDim slideOrder(1 To ActiveWindow.Selection.SlideRange.Count)
        
        'Collect all the IDs of the selected slides
        For i = 1 To ActiveWindow.Selection.SlideRange.Count
            slideOrder(i) = ActiveWindow.Selection.SlideRange(i).SlideIndex
        Next
        
        'Sort them with the QSort Algorithm
        'By Chip Pearson, www.cpearson.com, chip@cpearson.com
        QSortInPlace slideOrder
                
        'Iterate over the slides in Index order
        For o = 1 To UBound(slideOrder)
            If ActivePresentation.Slides(slideOrder(o)).Shapes.HasTitle Then
                'Build up the ToC Text
                strTitle = ActivePresentation.Slides(slideOrder(o)).Shapes.Title.TextFrame.TextRange.Text
                strSel = strSel & strTitle & vbCrLf
            End If
        Next
        
        'Create the summary slide before the first slide in the selection
        Set summary = ActivePresentation.Slides.Add(slideOrder(1), ppLayoutText)
        'Add the title
        summary.Shapes(1).TextFrame.TextRange = "Module Summary"
        'Add the ToC text
        summary.Shapes(2).TextFrame.TextRange = strSel
        
        ' By popular demand...! ;)
        If CreateHyperlinks Then
            'Add Hyperlinks :)
            For o = 1 To UBound(slideOrder)
                If ActivePresentation.Slides(slideOrder(o) + 1).Shapes.HasTitle Then
                    'Build up the ToC Text
                    strTitle = ActivePresentation.Slides(slideOrder(o) + 1).Shapes.Title.TextFrame.TextRange.Text
                    With summary.Shapes(2).TextFrame.TextRange.Paragraphs(o).ActionSettings(ppMouseClick)
                        .Action = ppActionHyperlink
                        .Hyperlink.Address = ""
                        .Hyperlink.SubAddress = ActivePresentation.Slides(slideOrder(o) + 1).SlideID & "," & ActivePresentation.Slides(slideOrder(o) + 1).SlideIndex & "," + strTitle
                    End With
                End If
            Next
        End If
    End If
End Sub
  
'''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
''' InsertSummaryWithHyperlinks()
''' by Joel Jeffery (http://joelblogs.co.uk) August 2010
''' Creates a Summary Slide for PowerPoint 2010
''' (and probably 2007 too!) with Hyperlinks
''' Usage: Select Slides (e.g. in Slide Sorter) and run
''' this macro.
''' License: Creative Commons Public Domain 2010
'''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
Sub InsertSummaryWithHyperlinks()
    InsertSummary CreateHyperlinks:=True
End Sub

To the extent possible under law, Joel Jeffery has waived all copyright and related or neighbouring rights to InsertSummary() and InsertSummaryWithHyperlinks() Macros for PowerPoint 2010. This work is published from United Kingdom. Why am I bothering to licensed this under Creative Commons? Because some folks are selling similar functionality as a PowerPoint Add-In and I think it should be free. Enjoy!

Technorati Tags: Macro, PowerPoint 2010, VBA

Tags : Macro, PowerPoint 2010, VBA

Automatically Create Summary Slides in PowerPoint 2010 for Free!

Filed Under : Code Samples and Downloads,Computers and Internet,Development,Training by Joel Jeffery

Aug.13,2010

*UPDATE* Please see part two of this blog post for an updated version that creates a auto summary slides for PowerPoint 2010 with hyperlinks!

Download the Create Summary Slide Macro PowerPoint 2010 slide deck here.

Not strictly SharePoint Architect related, but I cooked this VBA script up whilst working on my latest SharePoint 2010 Developer courseware.

In PowerPoint 2003 and earlier there was a button you could press that would automagically create a Summary Slide or Table of Contents Slide for you based upon slides you’d selected in Slide Sorter.

It got taken away in PowerPoint 2007, and it’s still missing in 2010! So tonight I wrote this macro. Apologies for any errors. It’s very, very late.

'''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
''' InsertSummary()
''' by Joel Jeffery (http://joelblogs.co.uk) August 2010
''' Creates a Summary Slide for PowerPoint 2010
''' (and probably 2007 too!)
''' Depends: Requires QSortInPlace by Chip Pearson
''' Usage: Select Slides (e.g. in Slide Sorter) and run
''' this macro.
''' License: Creative Commons Public Domain 2010
'''''''''''''''''''''''''''''''''''''''''''''''''''''''''''
Sub InsertSummary()
    Dim i As Integer
    Dim strSel As String, strTitle As String
    Dim summary As Slide
    
    'Only run if we've got something selected
    If ActiveWindow.Selection.SlideRange.Count > 0 Then
        'Array to hold the order of the slides...
        'We do this or we build the ToC in the order
        'in which the slides were selected :)
        Dim slideOrder() As Integer
        
        'Size this to the number of slides selected
        ReDim slideOrder(1 To ActiveWindow.Selection.SlideRange.Count)
        
        'Collect all the IDs of the selected slides
        For i = 1 To ActiveWindow.Selection.SlideRange.Count
            slideOrder(i) = ActiveWindow.Selection.SlideRange(i).SlideIndex
        Next
        
        'Sort them with the QSort Algorithm
        'By Chip Pearson, www.cpearson.com, chip@cpearson.com
        QSortInPlace slideOrder
                
        'Iterate over the slides in Index order
        For o = 1 To UBound(slideOrder)
            If ActivePresentation.Slides(slideOrder(o)).Shapes.HasTitle Then
                'Build up the ToC Text
                strTitle = ActivePresentation.Slides(slideOrder(o)).Shapes.Title.TextFrame.TextRange.Text
                strSel = strSel & strTitle & vbCrLf
            End If
        Next
        
        'Create the summary slide before the first slide in the selection
        Set summary = ActivePresentation.Slides.Add(slideOrder(1), ppLayoutText)
        'Add the title
        summary.Shapes(1).TextFrame.TextRange = "Module Summary"
        'Add the ToC text
        summary.Shapes(2).TextFrame.TextRange = strSel
    End If
End Sub
  

To the extent possible under law, Joel Jeffery has waived all copyright and related or neighbouring rights to InsertSummary() Macro for PowerPoint 2010. This work is published from United Kingdom. Why am I bothering to licensed this under Creative Commons? Because some folks are selling similar functionality as a PowerPoint Add-In and I think it should be free. Enjoy!

You’ll also need the QSortInPlace method by Chip Pearson.

To use, simply select all the slides you want to use for your summary (for instance, in Slide Sorter view) and run the InsertSummary() macro.